[아두이노] ESP32-CAM 스트리밍 + 플래시 제어

목  차

1. 서론

2. 본론

2.1. 아두이노 코드

2.2. 주요 코드 설명

2.3. 서버 작동

2.4. 한계 및 단점

3. 결론

---

1. 서론

 

  ESP32-CAM의 동영상 스트리밍 서버에 플래시 on-off 기능을 추가했습니다. 가장 기본적인 방법으로 정해진 웹페이지에 접속하면 반응하도록 구성되었습니다. 실시간으로 반응하지 않는 단점이 있지만, 대부분의 iot에 적용되는 방법이므로 한번쯤 봐두면 좋을 것 같아 공유합니다.

 

2. 본론

2.1. 아두이노 코드

  ESP32-CAM 예제를 돌릴 수 있다면, 추가 라이브러리가 필요하지 않습니다. 한 페이지에 모든 기능을 담았습니다.

#include "esp_camera.h"
#include <WiFi.h>
#include "esp_timer.h"
#include "img_converters.h"
#include "Arduino.h"
#include "fb_gfx.h"
#include "soc/soc.h" //disable brownout problems
#include "soc/rtc_cntl_reg.h"  //disable brownout problems
#include "esp_http_server.h"

//Replace with your network credentials
const char* ssid = "YOUR SSID";
const char* password = "YOUR PASSWORD";

#define PART_BOUNDARY "123456789000000000000987654321"

// This project was tested with the AI Thinker Model, M5STACK PSRAM Model and M5STACK WITHOUT PSRAM
#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27
#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22
#define LED                4

static const char* _STREAM_CONTENT_TYPE = "multipart/x-mixed-replace;boundary=" PART_BOUNDARY;
static const char* _STREAM_BOUNDARY = "\r\n--" PART_BOUNDARY "\r\n";
static const char* _STREAM_PART = "Content-Type: image/jpeg\r\nContent-Length: %u\r\n\r\n";

httpd_handle_t stream_httpd = NULL;

static esp_err_t stream_handler(httpd_req_t *req){
  camera_fb_t * fb = NULL;
  esp_err_t res = ESP_OK;
  size_t _jpg_buf_len = 0;
  uint8_t * _jpg_buf = NULL;
  char * part_buf[64];

  res = httpd_resp_set_type(req, _STREAM_CONTENT_TYPE);
  if(res != ESP_OK){
    return res;
  }

  httpd_resp_set_hdr(req, "Access-Control-Allow-Origin", "*"); //Added.

  while(true){
    fb = esp_camera_fb_get();
    if (!fb) {
      Serial.println("Camera capture failed");
      res = ESP_FAIL;
    } else {
      if(fb->width > 400){
        if(fb->format != PIXFORMAT_JPEG){
          bool jpeg_converted = frame2jpg(fb, 80, &_jpg_buf, &_jpg_buf_len);
          esp_camera_fb_return(fb);
          fb = NULL;
          if(!jpeg_converted){
            Serial.println("JPEG compression failed");
            res = ESP_FAIL;
          }
        } else {
          _jpg_buf_len = fb->len;
          _jpg_buf = fb->buf;
        }
      }
    }
    if(res == ESP_OK){
      size_t hlen = snprintf((char *)part_buf, 64, _STREAM_PART, _jpg_buf_len);
      res = httpd_resp_send_chunk(req, (const char *)part_buf, hlen);
    }
    if(res == ESP_OK){
      res = httpd_resp_send_chunk(req, (const char *)_jpg_buf, _jpg_buf_len);
    }
    if(res == ESP_OK){
      res = httpd_resp_send_chunk(req, _STREAM_BOUNDARY, strlen(_STREAM_BOUNDARY));
    }
    if(fb){
      esp_camera_fb_return(fb);
      fb = NULL;
      _jpg_buf = NULL;
    } else if(_jpg_buf){
      free(_jpg_buf);
      _jpg_buf = NULL;
    }
    if(res != ESP_OK){
      break;
    }
    //Serial.printf("MJPG: %uB\n",(uint32_t)(_jpg_buf_len));
  }
  return res;
}

static esp_err_t led_on_handler(httpd_req_t *req){ //Added custom function
  Serial.println("Led On");
  digitalWrite(LED, HIGH);
}

static esp_err_t led_off_handler(httpd_req_t *req){ //Added custom function
  Serial.println("Led Off");
  digitalWrite(LED, LOW);
}

void startCameraServer(){
  httpd_config_t config = HTTPD_DEFAULT_CONFIG();
  config.server_port = 80;

  httpd_uri_t stream_uri = {
    .uri       = "/",
    .method    = HTTP_GET,
    .handler   = stream_handler,
    .user_ctx  = NULL
    };
  httpd_uri_t led_on_uri = { //Added custom function
    .uri       = "/led-on",
    .method    = HTTP_GET,
    .handler   = led_on_handler,
    .user_ctx  = NULL
    };
  httpd_uri_t led_off_uri = { //Added custom function
    .uri       = "/led-off",
    .method    = HTTP_GET,
    .handler   = led_off_handler,
    .user_ctx  = NULL
    };
  
  //Serial.printf("Starting web server on port: '%d'\n", config.server_port);
  if (httpd_start(&stream_httpd, &config) == ESP_OK) {
    httpd_register_uri_handler(stream_httpd, &stream_uri);
    httpd_register_uri_handler(stream_httpd, &led_on_uri); //Added custom function
    httpd_register_uri_handler(stream_httpd, &led_off_uri); //Added custom function
  }
}

void setup() {
  pinMode(LED, OUTPUT);
  WRITE_PERI_REG(RTC_CNTL_BROWN_OUT_REG, 0); //disable brownout detector
 
  Serial.begin(115200);
  Serial.setDebugOutput(false);
  
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG; 
  config.frame_size = FRAMESIZE_VGA;
  config.jpeg_quality = 10;
  config.fb_count = 2;
  
  // Camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    return;
  }

  // Wi-Fi connection
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  for (int i = 0; i < 2; i++){
    digitalWrite(LED, HIGH);
    delay(20);
    digitalWrite(LED, LOW);
    delay(500);
  }
  
  Serial.print("Camera Stream Ready! Go to: http://");
  Serial.print(WiFi.localIP());
  
  // Start streaming web server
  startCameraServer();
}

void loop() {
  delay(1);
}

2.2. 주요 코드 설명

static esp_err_t led_on_handler(httpd_req_t *req){ //Added custom function
  Serial.println("Led On");
  digitalWrite(LED, HIGH);
}

static esp_err_t led_off_handler(httpd_req_t *req){ //Added custom function
  Serial.println("Led Off");
  digitalWrite(LED, LOW);
}

void startCameraServer(){
  httpd_config_t config = HTTPD_DEFAULT_CONFIG();
  config.server_port = 80;

  httpd_uri_t stream_uri = {
    .uri       = "/",
    .method    = HTTP_GET,
    .handler   = stream_handler,
    .user_ctx  = NULL
    };
  httpd_uri_t led_on_uri = { //Added custom function
    .uri       = "/led-on",
    .method    = HTTP_GET,
    .handler   = led_on_handler,
    .user_ctx  = NULL
    };
  httpd_uri_t led_off_uri = { //Added custom function
    .uri       = "/led-off",
    .method    = HTTP_GET,
    .handler   = led_off_handler,
    .user_ctx  = NULL
    };
  
  //Serial.printf("Starting web server on port: '%d'\n", config.server_port);
  if (httpd_start(&stream_httpd, &config) == ESP_OK) {
    httpd_register_uri_handler(stream_httpd, &stream_uri);
    httpd_register_uri_handler(stream_httpd, &led_on_uri); //Added custom function
    httpd_register_uri_handler(stream_httpd, &led_off_uri); //Added custom function
  }
}

led-on, led-off를 구현하기 위한 주요 코드입니다.

led-on을 위해 총 3부분을 추가해야 합니다.

• httpd_uri_t led_on_uri {~}
• httpd_register_uri_handler(stream_httpd, &led_on_uri);
• static esp_err_t led_off_handler(httpd_req_t *req) {~}

2.3. 서버 작동

• 실행주소/ : 카메라 스트리밍 (http://192.168.0.XX/)
• 실행주소/led-on : 플래시 켜짐
• 실행주소/led-off : 플래시 꺼짐

 

2.4. 한계 및 단점

  각 웹페이지에 접속해야 해서 스트리밍을 보며 플래시 제어가 되지 않습니다. 물론, 현재 코드에서 수정을 통해 각 페이지마다 스트리밍 하도록 구성할 수 있지만, 효과적인 방법이 아니라고 생각되어 구현하지 않았습니다.

 

 

3. 결론

 정해진 웹 주소에 접속해 영상 스트리밍, 플래시를 켜고 끄는 서버를 만들었습니다. 실시간으로 반응하지 않는 단점이 있는데, 이후 WebSocket 서버를 통해 실시간 동작하는 방법을 소개하겠습니다.

[끝]/